%,MX-O,

;
; = = = = = = = = = = = = = = = = = = = = = = = = = = = =
;
;TEL :
;FAX :
;e-mail :
;
; = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
;
;CLIENTE :
;MAQUINA : FRESADORA HELLER PF10-1000
;DATA : JULHO / 2008
;
; = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
;
;**********************************************************************
;DEFINICAO DE VARIAVEIS ***********************************************
;**********************************************************************
;
;**********************************************************************
;CONECTOR X9 **********************************************************
;**********************************************************************
;
DEF IG02_EMER_OK I1 ;EMERGENCIA OK
DEF IG02_COMANDO I3 ;COMANDO LIGADO
DEF IG02_TEMP_ARM I5 ;SUPERVISAO TEMPERATURA NO ARMARIO
DEF IG02_EMER_ARM I7 ;EMERGENCIA ARMARIO
DEF IG02_EMER_COM I9 ;EMERGENCIA PAINEL COMANDO
DEF IG10_DISJ_MP I11 ;DISJ_MOTOR_PRINCIPAL
DEF IG30_DISJ_DR_X I13 ;SUPERVISAO ALIMENTACAO DRIVE X
DEF IG30_LIM_X+ I15 ;LIMITE HARDWARE X+
DEF IG30_LIM_X- I17 ;LIMITE HARDWARE X-
DEF IG40_DISJ_DR_Z I19 ;SUPERVISAO ALIMENTACAO DRIVE Z
DEF IG40_LIM_Z+ I21 ;LIMITE HARDWARE Z+
DEF IG40_LIM_Z- I23 ;LIMITE HARDWARE Z-
DEF IG85_DISJ_MTREF I25 ;SUPERV. MOTOR REFRIGERACAO
DEF IG91_DISJ_MTFF I27 ;DISJ MOTOR REFRIGERACAO FERRAMENTA
DEF IG91_PED_FIX_FER I29 ;PEDAL FIXAR FERRAMENTA
DEF IG91_PED_SOL_FER I31 ;PEDAL SOLTAR FERRAMENTA
;
DEF IG01_DISJ_220_AUX I2 ;DISJUNTOR ALIM. 220VAC - AUX
DEF IG01_DISJ_24_IN I4 ;DISJUNTOR ALIM. 24VCC - ENTRADAS
DEF IG01_DISJ_24_OUT I6 ;DISJUNTOR ALIM. 24VCC - SAIDAS
DEF IG01_DISJ_24_FR I8 ;DISJUNTOR ALIM. 24VCC - FREIOS
DEF IG01_DISJ_220_COM I10 ;DISJUNTOR ALIM. 220VAC - COMANDO
DEF IG13_DISJ_M_CIRC I12 ;DISJUNTOR MOTOR BOMBA CIRCULACAO
DEF IG13_PRES+FILTRO I14 ;PRESSAO + FILTRO UNID. REFRIG. OLEO
DEF IG13_CIRC_OLEO I16 ;FLUXO CIRCULACAO DE OLEO
DEF IG35_DISJ_DR_Y I18 ;SUPERVISAO ALIMENTACAO DRIVE EIXO Y
DEF IG35_LIM_Y+ I20 ;LIMITE HARDWARE Y+
DEF IG35_LIM_Y- I22 ;LIMITE HARDWARE Y-
DEF IG80_DISJ_LUB I24 ;DISJUNTOR MOTOR LUBRIF. GUIAS
DEF IG80_NIV_LUB I26 ;NIVEL OLEO LUBRIF. GUIAS
DEF IG80_PRES_LUB I28 ;PRESSAO LUBRIF. GUIAS
DEF IG87_DISJ_TC I30 ;DISJUNTOR MOTOR TRANSP. CAVACOS
DEF IG87_TC_ENROSC I32 ;LIMITE - TRANSP. CAVACOS ENROSCADO
;
;**********************************************************************
;CONECTOR X10 *********************************************************
;**********************************************************************
;
DEF OG02_EMER_CNC O1 ;LIBERACAO EMERGENCIA CNC
DEF OG13_MT_CIRC O3 ;LIGA MOTOR CIRCULACAO OLEO
DEF OG13_CIRC_GAS O5 ;LIBERA CIRCULACAO GAS
DEF OG85_MT_REFR O7 ;LIGA MOTOR REFRIGERACAO FERRAMENTA
DEF OG91_MT_FIXAR O9 ;MOTOR - FIXAR FERRAMENTA
DEF OG91_MT_SOLTAR O11 ;MOTOR - SOLTAR FERRAMENTA
DEF OG40_FREIO_Z O13 ;LIBERACAO DE FREIO EIXO Z
DEF OG30_DR_ENAB_XYZ O15 ;DRIVER ENABLE XYZ
DEF OG05_ILUM_MAQ O17 ;ILUMINACAO DA MAQUINA
DEF OG02_COM_LAM O19 ;LAMPADA - COMANDO
DEF OG02_CANC_LAM O21 ;LAMPADA - CANCELA EMERG. DOS EIXOS
DEF OG10_FREIO_SP O23 ;LIBERACAO FREIO SPINDLE
;
DEF IG02_LIG_COM I33 ;BOTAO LIGA COMANDO
DEF IG02_CANC_EMERG I35 ;BOTAO CANCELA EMERGENCIA DOS EIXOS
DEF IG30_EMERG_EIXOS I37 ;ACIONADO FDC EMERGENCIA EIXOS
DEF IG01_DISJ_DR I39 ;DISJUNTOR ALIMENTACAO TRAFO_DRIVERS
;
DEF OG02_CANC_EMERG O2 ;CANCELA EMERGENCIA DOS EIXOS
DEF OG02_LIG_COM O4 ;LIGA COMANDO
DEF OG02_QUIT_EMER O6 ;QUITACAO EMERGENCIA
DEF OG10_MP_CW O8 ;MOTOR PRINCIPAL - SENT. HORARIO
DEF OG10_MP_CCW O10 ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
DEF OG10_MP_TRIANG O12 ;MOTOR PRINCIPAL - TRIANGULO
DEF OG10_MP_ESTRELA O14 ;MOTOR PRINCIPAL - ESTRELA
DEF OG80_MT_LUB O16 ;MOTOR LUBRIFICACAO GUIAS
DEF OG87_MT_TC_AVA O18 ;MOTOR TRANSP.CAVACOS - AVANCAR
DEF OG87_MT_TC_RET O20 ;MOTOR TRANSP.CAVACOS - RETORNAR
DEF OG30_POT_DR_XYZ O22 ;ALIMENTACAO DRIVERS XYZ
DEF OG30_SP_ENAB_XYZ O24 ;SPEED ENABLE XYZ
;
DEF IG30_DR_OK_XYZ I34 ;DRIVERS OK - XYZ
DEF IG30_REF_X I36 ;MICRO DE REFERENCIA EIXO X
DEF IG35_REF_Y I38 ;MICRO DE REFERENCIA EIXO Y
DEF IG40_REF_Z I40 ;MICRO DE REFERENCIA EIXO Z
;
;**********************************************************************
;MEMORIAS *************************************************************
;**********************************************************************
;
DEF ZERO M10 ; SEMPRE 0
DEF UM M11 ; SEMPRE 1
DEF COMANDO M200 ; COMANDO LIGADO
;
;**********************************************************************
;TECLAS ***************************************************************
;**********************************************************************
DEF ENVIATEC M1200 ;flag enviar codigo de tecla
DEF rCOD-TEC R55 ;codigo da tecla
DEF ULTECLA R60 ;indica qual a ultima tecla aceita pelo CNC
DEF ENVIOK M120 ;indica que a tecla foi enviada ao CNC corretamente
DEF rTECLADO R58 ;utilizado para indicar ao CNC a procedencia das teclas
DEF nTEC-CNC 0 ;tecla proveniente do CNC
DEF nTEC-PLC 1 ;tecla proveniente do PLC
DEF tecF1 $FC00 ;F1
DEF tecF2 $FC01 ;F2
DEF tecF3 $FC02 ;F3
DEF tecF4 $FC03 ;F4
DEF tecF5 $FC04 ;F5
DEF tecF6 $FC05 ;F6
DEF tecF7 $FC06 ;F7
DEF tecMAIN $FFF4 ;MAIN MENU
DEF tecENTER $0D ;ENTER
DEF tecSTART $FFF1 ;START
DEF tecESC $1B ;ESC
DEF tec-0 $30 ;0
DEF tec-1 $31 ;1
DEF tec-2 $32 ;2
DEF tec-3 $33 ;3
DEF tec-4 $34 ;4
DEF tec-5 $35 ;5
DEF tec-6 $36 ;6
DEF tec-7 $37 ;7
DEF tec-8 $38 ;8
DEF tec-9 $39 ;9
;
;**********************************************************************
;CICLO INICIAL ********************************************************
;**********************************************************************
;
CY1
;
() = ERA M1 1000 ;RESETAR MARCAS
= ERA O1 O24 ;RESETAR SAIDAS
= ERA T1 255 ;RESETAR TEMPORIZADORES
= ERA C1 255 ;RESETAR CONTADORES
= ERA R1 499 ;RESETAR REGISTRADORES
;
() =MOV $FC06 R37 0032 ;BLOCO-A-BLOCO
;
END
;
PRG
REA
;
;MEMORIAS DE JUMPER ***************************************************
;
NOT ZERO = RES ZERO
NOT ZERO = SET UM
;
;FUNCOES E PARAMETROS DE COMUNICACAO **********************************
;
()=CNCWR(R700,GUP2105,M1) ;ESCRITA POTENCIA MOTOR X
()=CNCWR(R701,GUP2106,M1) ;ESCRITA POTENCIA MOTOR Y
()=CNCWR(R702,GUP2107,M1) ;ESCRITA POTENCIA MOTOR Z
;
()=CNCRD(GUP1000,R6,M1) ;PARAMETRO_LUBRIFICACAO GUIAS
()= MLS R6 60000 R9 ;AJUSTAR VALOR TELA USUARIO EM MIN.
()=CNCRD(GUP1002,R8,M1) ;PARAMETRO_LUBRIF.
()= MLS R8 1000 R11 ;AJUSTAR VALOR TELA USUARIO EM SEG.
()=CNCRD(KEY,R13,M1) ;LEITURA TECLA ACIONADA
;
NOT COMANDO
AND NOT IG02_EMER_OK
AND ( ( CPS R13 EQ $FFF4 )
 OR ( CPS R13 EQ $FFF3))
= M202 ;PULSO QUITA_EMERGENCIA

;
;EMERGENCIAS **********************************************************
;
/ALARM ;SEM ALARME PRESENTE
AND CNCREADY ;CNC PRONTO
AND PLCREADY ;PLC PRONTO
= OG02_EMER_CNC ;SAIDA EMERGENCIA
= /EMERGEN ;SAIDA DE EMEGENCIA
;
OG02_EMER_CNC ;SAIDA DE EMERGENCIA
AND ( RESETOUT OR M202) ;TECLA RESET / MAIN MENU / ESC
= OG02_QUIT_EMER ;QUITACAO EMERGENCIA
;
IG02_EMER_ARM ;BOTAO-EMERG_ARMARIO
= ERR3 ;ERRO-EMERG_ARMARIO
;
IG02_EMER_COM ;BOTAO-EMERG_COMANDO
= ERR4 ;ERRO-EMERG_COMANDO
;
;SUPERVISAO DOS DISJUNTORES *******************************************
;
NOT IG01_DISJ_220_AUX ;DISJUNTOR ALIMENTACAO 220VCA - AUX
AND NOT ERR5 ;NAO MSG-01F25 DESARMADO
= MSG2 ;MSG-01Q14/01F15 DESARMADO
;
NOT IG01_DISJ_24_IN ;DISJUNTOR ALIM. 24VCC - ENTRADAS
= ERR5 ;ERRO-01F25 DESARMADO
;
NOT IG01_DISJ_24_OUT ;DISJUNTOR ALIM. 24VCC - SA DAS
AND NOT ERR5 ;NAO MSG-01F25 DESARMADO
= ERR6 ;ERRO-01F26 DESARMADO
;
NOT IG01_DISJ_24_FR ;DISJUNTOR ALIM. 24VCC - FREIOS
AND NOT ERR5 ;NAO MSG-01F25 DESARMADO
= ERR7 ;ERRO-01F27 DESARMADO
;
NOT IG01_DISJ_220_COM ;DISJUNTOR ALIM. 220VCA - COMANDO
AND NOT ERR5 ;NAO MSG-01F25 DESARMADO
= ERR1 ;ERRO-01Q33/01F34 DESARMADO
;
NOT IG01_DISJ_DR ;DISJUNTOR ALIM. TRAFO_DRIVERS

AND NOT ERR5 ;NAO MSG-01F25 DESARMADO

= ERR13 ;ERRO-01Q17 DESARMADO
;
IG02_TEMP_ARM ;SUPERVISAO TEMPERATURA NO ARMARIO
AND NOT ERR5 ;NAO MSG-01F25 DESARMADO
= MSG3 ;MSG-ALTA TEMP_ARMARIO
;
;LIGA COMANDO *********************************************************
;
IG02_EMER_OK ;EMERGENICA OK
AND OG02_EMER_CNC ;SAIDA EMERGENCIA
AND NOT MSG2 ;MSG-01Q14/01F15 DESARMADO
AND NOT ERR13 ;ERRO-01Q17 DESARMADO
AND NOT ERR5 ;ERRO-01F25 DESARMADO
 AND NOT ERR6 ;ERRO-01F26 DESARMADO
AND NOT MSG3 ;MSG-ALTA TEMP_ARMARIO
AND NOT ERR7 ;ERRO-01F27 DESARMADO
AND NOT ERR1 ;ERRO-01Q33/01F34 DESARMADO
AND DFU IG02_LIG_COM ;BOTAO LIGA COMANDO
= SET COMANDO ;LIGA COMANDO
;
NOT IG02_EMER_OK ;EMERGENCIA OK
= RES COMANDO ;DESLIGA COMANDO
;
COMANDO ;LIGA COMAND0
= OG02_LIG_COM ;LIGA COMANDO
;
M2017 ;PISCA-PISCA
AND NOT COMANDO ;COMANDO
= MSG1 ;MSG-COMANDO DESLIGADO
;
MSG1 ;MSG-COMANDO DESLIGADO
OR COMANDO ;COMANDO
= OG02_COM_LAM ;LAMPADA - COMANDO
;
;EMERGENCIA NOS EIXOS *************************************************
;
NOT IG02_EMER_ARM ;EMERGENCIA ARMARIO
AND NOT IG02_EMER_COM ;EMERGENCIA COMANDO
AND ( MSG30 ;EMERGENCIA EIXO X
OR MSG31 ;EMERGENCIA EIXO Y
OR MSG32 ) ;EMERGENCIA EIXO Z
AND ( OG02_CANC_EMERG ;ACIONADO EMERGENCIA DOS EIXOS
OR M2017 ) ;PISCA-PISCA
= OG02_CANC_LAM ;LAMP. - CANCELA EMERG DOS EIXOS
;
NOT IG02_EMER_ARM ;EMERGENCIA ARMARIO
AND NOT IG02_EMER_COM ;EMERGENCIA COMANDO
AND ( MSG30 ;EMERGENCIA EIXO X
OR MSG31 ;EMERGENCIA EIXO Y
OR MSG32 ) ;EMERGENCIA EIXO Z
AND ( NOT IG02_EMER_OK ;EMERGENCIA OK
OR IG02_CANC_EMERG ) ;BOTAO - CANCELA EMERG DOS EIXOS
AND IG02_CANC_EMERG ;BOTAO - CANCELA EMERG DOS EIXOS
= OG02_CANC_EMERG ;LAMPADA EMERGENCIA DOS EIXOS
;
;RESET DE MENSAGENS E ERROS *******************************************
;
NOT COMANDO ;COMANDO
= ERA M4004 4127 ;APAGA MSGS EXCETO MSG1 MSG5
;
RESETOUT ;RESET
= ERA M4500 4563 ;APAGA ERROS
= ERA M4001 4074 ;APAGA MENSAGENS
= ERA M4076 4127 ;APAGA MENSAGENS
;
;CHAMADA DOS BLOCOS ***************************************************
;
() = CAL L5 ;ILUMINACAO MAQUINA
() = CAL L8 ;CNC 8055
() = CAL L10 ;SPINDLE
() = CAL L13 ;HIDRAULICO
() = CAL L30 ;EIXO X
() = CAL L35 ;EIXO Y
() = CAL L40 ;EIXO Z
() = CAL L80 ;LUBRIFICACAO DOS EIXOS
() = CAL L85 ;REFRIGERACAO FERRAMENTA
() = CAL L87 ;TRANSPORTADOR DE CAVACO
() = CAL L91 ;FIXACAO FERRAMENTA
;
END
;
;**********************************************************************
L5; ILUMINACAO MAQUINA ************************************************
;**********************************************************************
;
DFU B15R563 ;PULSO TECLA LIGA LAMPADA
AND NOT M52 ;MEM_AUX
AND OG05_ILUM_MAQ ;LAMPADA
= RES OG05_ILUM_MAQ ;DESLIGA LAMPADA
= SET M52 ;LIGA MEM_AUX
;
DFU B15R563 ;PULSO TECLA LIGA LAMPADA
AND NOT M52 ;MEM_AUX
AND NOT OG05_ILUM_MAQ ;LAMPADA
= SET OG05_ILUM_MAQ ;LIGA LAMPADA
= SET M52 ;LIGA MEM_AUX
;
NOT B15R563 ;SEM A TECLA
= RES M52 ;DESLIGA MEM_AUX
;
END
;
;**********************************************************************
L8; CNC 8055 **********************************************************
;**********************************************************************
;
;DECODIFICACAO DE FUNCOES M,S e T *************************************
;
NOT MANUAL ;NAO MODO DE OPERACAO MANUAL
AND NOT M1900 ;M0 - PARADA PROGRAMADA
AND ( IG91_PED_FIX_FER ;PEDAL FIXAR FERRAMENTA
OR IG91_PED_SOL_FER ;PEDAL SOLTAR FERRAMENTA
OR B29R562 ;TECLA SOLTAR FERRAMENTA
OR B13R562 ) ;TECLA FIXAR FERRAMENTA
= MSG82 ;MSG82-SOMENTE EM JOG-MANUAL
;
DFU MSTROBE ;FUNCAO M
OR DFU SSTROBE ;FUNCAO S
OR DFU TSTROBE ;FUNCAO T
= TG1 51 100 ;AUX. AUXEND
;
DFU MSTROBE ;FUNCAO M
= CAL L100
= M801 ;DECODIF. FUNCAO "M"
;
DFD M801 ;DECODIF. FUNCAO "M"
= ERA M900 999 ;RESETAR CODIGOS M
;
;FEEDHOLD, START, STOP, XFERINH, AUXEND *******************************
;
OG02_EMER_CNC ;LIBERACAO EMERGENCIA CNC
 = /STOP ;STOP CNC
= /XFERINH ;BLOQUEIO LEITURA BL
;
OG02_EMER_CNC ;LIBERACAO EMERGENCIA CNC
AND (( NOT RAPID ;NAO RAPIDO-G00
AND ( REVOK
OR O12 )
AND (( OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
OR OG10_MP_CCW ) ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
AND OG10_MP_TRIANG )) ;MOTOR PRINCIPAL - TRIANGULO
OR ( NOT MDI ;NAO MDI
AND NOT AUTOMAT ) ;NAO AUTO
OR RAPID ) ;RAPIDO-G00
= /FEEDHOL ;LIB. DE EIXOS
;
START ;START
AND COMANDO ;COMANDO
AND (( AUTOMAT ;AUTO
OR SBOUT ) ;BLOCO-BLOCO
AND M803 ;EIXOS REFERENCIADOS
OR NOT AUTOMAT ) ;NAO AUTO
AND NOT MSG11 ;FALHA SIST_REFRIG_OLEO
AND NOT MSG12 ;FALHA SIST_REFRIG_OLEO
AND NOT MSG13 ;FALHA SIST_REFRIG_OLEO
AND NOT MSG40 ;FALHA SIST_LUB
AND NOT MSG41 ;FALHA SIST_LUB
AND NOT MSG42 ;FALHA SIST_LUB
AND NOT MSG43 ;FALHA SIST_LUB
= CYSTART ;START CNC
;
NOT T51 ;TEMPO STROBE M/S/T
= AUXEND ;EXECUTADO M,S,T.
;
;AVANCOS **************************************************************
;
() = CNCRD(PRGF,R1,M1) ;LEITURA "F" / G94
() = CNCRD(PRGFPR,R2,M1) ;LEITURA "F" / G95
;
( AUTOMAT ;AUTO
OR MDI ;MDI
OR SBOUT ) ;BLOCO-BLOCO
AND( NOT RAPID ;RAPIDO-G00
AND ( CPS R1 EQ 0 ;F=0 / G94
AND CPS R2 EQ 0 ) ) ;F=0 / G95
= M802 ;BLOQ. EIXOS(F=0/N><N PROG)
;
;REFERENCIA DOS EIXOS *************************************************
;
( REFPOIN1 ;EIXO X REFERENCIADO
AND REFPOIN2 ;EIXO Y REFERENCIADO
AND REFPOIN3 ) ;EIXO Z REFERENCIADO
OR M804 ;(M99)BY-PASS REF_EIXOS
= M803 ;EIXOS REFERENCIADOS
;
DFU M1999 ;(M99)
= SET M804 ;BY-PASS REF_EIXOS
;
RESETOUT ;RESET
OR NOT COMANDO ;COMANDO
 = RES M804 ;CANCELA BY-PASS REF_EIXOS
;
;FIXA BLOCO-A-BLOCO ***************************************************
;
NOT M18 ;
AND DFU AUTOMAT ;
AND NOT SBOUT ;
= TG1 99 500 ;
= SET M18 ;
;
NOT AUTOMAT ;
AND NOT SBOUT ;
= RES M18 ;
;
T99 ;
= MOV 1 R36 ;
= TG2 98 100 ;
;
T98 ;
= M19 ;
;
NOT T99 ;
= MOV 0 R36 ;
;
() = CNCWR(R36,KEYSRC,M1) ;
;
DFU M19 ;
= CNCWR(R37,KEY,M1) ;
;
END
;
;**********************************************************************
L10; SPINDLE **********************************************************
;**********************************************************************
;
;LIBERACAO SPINDLE ****************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT MSG76 ;MSG-FERRAMENTA SOLTA
AND ( DFU M1903 ;M3 - GIRA SENTIDO HORARIO
OR DFU M1904 ) ;M4 - GIRA SENTIDO ANTI-HORARIO
= SET M110 ;LIGA FUSO
;
NOT COMANDO ;COMANDO LIGADO
OR DFU M1905 ;M5 - DESLIGA SPINDLE
OR DFU M1930 ;M30 - FIM DE PROGRAMA
OR RESETOUT ;RESET CNC
OR ERR18 ;ERRO-10Q12 DESARMADO
= RES M110 ;DESLIGA FUSO
= RES M1655 ;BLOQ. FUSO - TECLA
= RES M1903
= RES M1904
;
NOT M110 ;DESLIGA FUSO
AND NOT M1655 ;NAO BLOQ. FUSO - TECLA
= RES M13 ;CANCELA MOVIMENTO M3
= RES M14 ;CANCELA MOVIMENTO M4
;
;DFD M1903 ;PARADA SPINDLE SENTIDO HORARIO
; AND NOT M1900 ;NAO PARADA PROGRAMADA
; = RES M13 ;DESLIGA MEMORIA M13
;
;DFD M1904 ;PARADA SPINDLE SENTIDO ANTIHORARIO
; AND NOT M1900 ;NAO PARADA PROGRAMADA
; = RES M14 ;DESLIGA MEMORIA M14
;
DFU M1903 ;M3 - SPINDLE SENTIDO HORARIO
= SET M13 ;SPINDLE SENTIDO HORARIO
;
DFU M1904 ;M4 - SPINDLE SENTIDO ANTIHORARIO
= SET M14 ;SPINDLE SENTIDO ANTIHORARIO
;
M1900 ;M0 - PARADA PROGRAMADA
AND DFU START ;TECLA CYCLE START
= RES M1900 ;RESET MEMORIA DE PARADA PROGRAMADA
;
MSG76 ;MSG-FERRAMENTA SOLTA
OR ( M110 ;FUSO LIGADO
AND ( DFU B20R562 ;TECLA - SPINDLE STOP
AND ( RAPID ;AVANCO RAPIDO - G0
OR FHOUT )))
= SET M1655 ;BLOQ. FUSO - TECLA
;
( NOT COMANDO ;COMANDO DESLIGADO
OR DFU B17R562 ;TECLA - SPINDLE CW
OR DFU B22R562 ) ;TECLA - SPINDLE CCW
AND NOT MSG76 ;MSG-FERRAMENTA SOLTA
= RES M1655 ;RESET BLOQ. FUSO - TECLA
;
M111 ;LIBERA FUSO
AND ( ( NOT OG10_MP_CW ;SPINDLE PARADO HORARIO
AND NOT OG10_MP_CCW ) ;SPINDLE PARADO ANTIHORARIO
OR OG10_MP_CW ;SPINDLE SENTIDO HORARIO
OR OG10_MP_CCW ) ;SPINDLE SENTIDO ANTIHORARIO
= OG10_FREIO_SP ;LIBERA FREIO DO SPINDLE
= TG2 9 700 ;TEMPO PARA LIBERACAO DE GIRO
;
M110 ;FUSO LIGADO
AND NOT M1655 ;NAO BLOQ. FUSO - TECLA
AND NOT ERR18 ;ERRO-10Q12 DESARMADO
AND NOT MSG76 ;MSG-FERRAMENTA SOLTA
AND NOT OG91_MT_SOLTAR ;MOTOR SOLTAR FERRAM.
AND NOT OG91_MT_FIXAR ;MOTOR FIXAR FERRAM.
AND NOT M1900 ;M0 - PARADA POGRAMADA
= M111 ;LIBERA FUSO
;
;SUPERVISAO E SEGURANCA ***********************************************
;
NOT OG10_MP_CW ;MOTOR PARADO SENTIDO HORARIO
AND NOT OG10_MP_CCW ;MOTOR PARADO SENTIDO ANTI-HORARIO
= TG2 31 5000 ;TEMPO P/ LIB_FIX_FERR.
;
DFU COMANDO ;LIGANDO COMANDO
OR DFD OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
OR DFD OG10_MP_CCW ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
= SET M1010 ;MEMORIA TEMPO PARA REVERSAO
;
OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
 OR OG10_MP_CCW ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
= RES M1010 ;MEMORIA TEMPO PARA REVERSAO
;
M1010 ;MEMORIA TEMPO PARA REVERSAO
= TG2 11 2000 ;TEMPO PARA REVERSAO
;
COMANDO ;COMANDO LIGADO
AND NOT IG10_DISJ_MP ;DISUNTOR MOTOR PRINCIPAL
= ERR14 ;ERRO-10Q12 DESARMADO
;
;SENTIDO DE GIRO ******************************************************
;
T9 ;TEMPO LIBERACAO FREIO SPINDLE
AND ( T11 ;TEMPO PARA REVERSAO
OR OG10_MP_CW ) ;MOTOR PRINCIPAL - SENT. HORARIO
AND M13 ;M3 - SPINDLE SENTIDO HORARIO
AND NOT OG10_MP_CCW ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
= OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
;
T9 ;TEMPO LIBERACAO FREIO SPINDLE
AND ( T11 ;TEMPO PARA REVERSAO
OR OG10_MP_CCW ) ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
AND M14 ;M4 - SPINDLE SENTIDO ANTI-HORARIO
AND NOT OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
= OG10_MP_CCW ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
;
;ESTRELA / TRIANGULO **************************************************
;
( OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
OR OG10_MP_CCW ) ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
AND NOT T10 ;TEMPO DE PARTIDA ESTRELA
AND NOT OG10_MP_TRIANG ;NAO FECHAMENTO EM TRIANGULO
= OG10_MP_ESTRELA ;FECHAMENTO ESTRELA
;
OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
OR OG10_MP_CCW ;MOTOR PRINCIPAL - SENT.ANTI-HORARIO
= TG2 10 4000 ;TEMPO DE PARTIDA ESTRELA
;
( OG10_MP_CW ;MOTOR PRINCIPAL - SENT. HORARIO
OR OG10_MP_CCW ) ;MOTOR PRINCIPAL - SENT. ANTI-HORARIO
AND T10 ;TEMPO DE PARTIDA ESTRELA
AND NOT OG10_MP_ESTRELA ;NAO FECHAMENTO ESTRELA
= OG10_MP_TRIANG ;FECHAMENTO TRIANGULO
;
END
;
;**********************************************************************
L13; HIDRAULICO *******************************************************
;**********************************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT IG13_DISJ_M_CIRC ;DISJUNTOR
= MSG11 ;MSG-FALHA MOTOR HIDR
;
COMANDO ;COMANDO
AND IG13_PRES+FILTRO ;FILTRO
= SET MSG13 ;MSG-FLUXO/PRESSAO
NOT COMANDO ;COMANDO DESLIGADO
= RES MSG13 ;CANCELA MENSAGEM DE FLUXO/PRESSAO
;
T13 ;TEMPO PARA CONTROLE FLUXO
= MSG12 ;MSG - FALHA NO FLUXO CIRCUL.OLEO
;
COMANDO ;COMANDO LIGADO
AND NOT MSG11 ;MSG-FALHA MOTOR HIDR
AND NOT MSG13 ;SEM FALHA FLUXO/PRESSAO
= OG13_MT_CIRC ;BOMBA HIDRAULICA CIRCULACAO
;
COMANDO ;COMANDO
AND NOT IG13_CIRC_OLEO ;FALTA SINAL FLUXO
= TG2 13 2000 ;TEMPO PARA CONTROLE FLUXO
;
COMANDO ;COMANDO LIGADO
AND NOT MSG11 ;MSG DISJUNTOR
AND IG13_CIRC_OLEO ;CONTROLE FLUXO
AND OG13_MT_CIRC ;MOTOR CIRCULACAO
= OG13_CIRC_GAS ;CIRCULACAO DE GAS
;
END
;
;**********************************************************************
L30; EIXO X ***********************************************************
;**********************************************************************
;
;SUPERVISAO DE FALHAS *************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT IG30_DISJ_DR_X ;SUPERVISAO ALIM. DO DRIVER EIXO X
= ERR15 ;ERRO-30Q12 DESARMADO
;
;COMANDO ;COMANDO LIGADO
; AND NOT IG30_DR_OK_XYZ AND ZERO ;DRIVE OK XYZ
; = ERR8 ;ERRO-FALHA NOS DRIVERS XYZ
;
;LIBERACOES DAS POTENCIAS XYZ *****************************************
;
OG02_EMER_CNC ;SAIDA DE EMERGENCIA
AND COMANDO ;COMANDO LIGADO
AND NOT ERR8 ;ERRO-FALHA NOS DRIVERS XYZ
AND NOT ERR15 ;ERRO-30Q12 DESARMADO
AND NOT ERR16 ;ERRO-35Q12 DESARMADO
AND NOT ERR17 ;ERRO-40Q12 DESARMADO
= SET OG30_POT_DR_XYZ ;ALIMENTACAO DRIVERS XYZ
= TG2 3 500 ;POTENCIA FONTE
= TG3 4 1000 ;TEMPO PARA DESLIGAR POTENCIA
;
NOT T4 ;NAO TEMPO PARA DESLIGAR POTENCIA
= RES OG30_POT_DR_XYZ ;DESLIGA POTENCIA
;
;LIBERACOES PARA EIXOS XYZ ********************************************
;
OG30_POT_DR_XYZ ;POTENCIA DOS DRIVERS LIGADA
AND IG30_DR_OK_XYZ OR UM ;DRIVER OK - XYZ
AND T3 ;POTENCIA FONTE
= TG2 5 1000 ;RETARDO P/ DRIVE ENABLE XYZ
;
;FIM DE CURSO *********************************************************
;
COMANDO ;COMANDO LIGADO
AND IG30_LIM_X+ ;LIMITE HARDWARE X+
= LIMIT+1 ;EIXO1 - X SOBRE LIMITE DE HARDWARE +
= MSG15 ;MSG-LIMITE X+
;
COMANDO ;COMANDO LIGADO
AND IG30_LIM_X- ;LIMITE HARDWARE X-
= LIMIT-1 ;EIXO1 - X SOBRE LIMITE DE HARDWARE -
= MSG16 ;MSG-LIMITE X-
;
NOT IG30_EMERG_EIXOS ;EMERGENCIA ACIONADA EIXOS
AND ( MSG15 ;MSG-LIMITE X+
OR MSG16 ) ;MSG-LIMITE X-
= MSG30 ;MSG-EMERGENCIA NO EIXO X
;
COMANDO ;COMANDO LIGADO
AND NOT MANUAL ;NAO MODO MANUAL
AND NOT REFPOIN1 ;EIXO X NAO REFERENCIADO
= MSG17 ;MSG-REFERENCIAR EIXO X
;
IG30_REF_X ;MICRO DE REFERENCIA EIXO X
= DECEL1 ;MICRO REFERENCIA X
;
;LIBERACOES ***********************************************************
;
T5 ;TEMPO DE LIBERACAO DO DRIVE
= DRENA1 ;DRIVE ENABLE EIXO X - CNC
= SERVO1ON ;SERVO LIGADO EIXO X - CNC
= TG3 6 500 ;TEMPO PARA SPEED ENABLE
= OG30_DR_ENAB_XYZ ;DRIVE ENABLE EIXOS XYZ
;
T6 ;TEMPO PARA SPEED ENABLE
= OG30_SP_ENAB_XYZ ;SPEED ENABLE EIXOS XYZ

= SPENA1 ;SPEED ENABLE EIXO X - CNC

;
NOT SPENA1 ;NAO SPEED ENABLE EIXOS X - CNC
= INHIBIT1 ;BLOQUEIO EIXO X
;
END
;
;**********************************************************************
L35; EIXO Y ***********************************************************
;**********************************************************************
;
;SUPERVISAO DE FALHAS *************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT IG35_DISJ_DR_Y ;SUPERVISAO ALIM. DO DRIVER EIXO Y
= ERR16 ;ERRO-35Q12 DESARMADO
;
;FIM DE CURSO *********************************************************
;
COMANDO ;COMANDO LIGADO
AND IG35_LIM_Y+ ;LIMITE HARDWARE Y+
= LIMIT+2 ;EIXO2 - Y SOBRE LIMITE DE HARDWARE +
= MSG20 ;MSG-LIMITE Y+
;
COMANDO ;COMANDO LIGADO
 AND IG35_LIM_Y- ;LIMITE HARDWARE Y-
= LIMIT-2 ;EIXO2 - Y SOBRE LIMITE DE HARDWARE -
= MSG21 ;MSG-LIMITE Y-
;
NOT IG30_EMERG_EIXOS ;EMERGENCIA ACIONADA EIXOS
AND ( MSG20 ;MSG-LIMITE Y+
OR MSG21 ) ;MSG-LIMITE Y-
= MSG31 ;MSG-EMERGENCIA NO EIXO Y
;
COMANDO ;COMANDO LIGADO
AND NOT MANUAL ;NAO MODO MANUAL
AND NOT REFPOIN2 ;EIXO Y NAO REFERENCIADO
= MSG22 ;MSG-REFERENCIAR EIXO Y
;
IG35_REF_Y ;MICRO DE REFERENCIA EIXO Y
= DECEL2 ;MICRO REFERENCIA Y
;
;LIBERACOES ***********************************************************
;
DRENA1 ;DRIVE ENABLE EIXO X - CNC
= DRENA2 ;DRIVE ENABLE EIXO Y - CNC
= SERVO2ON ;SERVO LIGADO EIXO Y - CNC
;
SPENA1 ;SPEED ENABLE EIXO X - CNC
=SPENA2 ;SPEED ENABLE EIXO Y - CNC
;
NOT SPENA2 ;NAO SPEED ENABLE EIXO Y - CNC
= INHIBIT2 ;BLOQUEIO EIXO Y
;
END
;
;**********************************************************************
L40; EIXO Z ***********************************************************
;**********************************************************************
;
;SUPERVISAO DE FALHAS *************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT IG40_DISJ_DR_Z ;SUPERVISAO ALIM. DO DRIVER EIXO Z
= ERR17 ;ERRO-40Q12 DESARMADO
;
COMANDO ;COMANDO LIGADO
AND IG40_LIM_Z+ ;LIMITE HARDWARE Z+
= LIMIT+3 ;EIXO3 - Z SOBRE LIMITE DE HARDWARE +
= MSG25 ;MSG-LIMITE Z+
;
COMANDO ;COMANDO LIGADO
AND IG40_LIM_Z- ;LIMITE HARDWARE Z-
= LIMIT-3 ;EIXO3 - Z SOBRE LIMITE DE HARDWARE -
= MSG26 ;MSG-LIMITE Z-
;
NOT IG30_EMERG_EIXOS ;EMERGENCIA ACIONADA EIXOS
AND ( MSG25 ;MSG-LIMITE Z+
OR MSG26 ) ;MSG-LIMITE Z-
= MSG32 ;MSG-EMERGENCIA NO EIXO Z
;
COMANDO ;COMANDO LIGADO
AND NOT MANUAL ;NAO MODO MANUAL
AND NOT REFPOIN3 ;EIXO Z NAO REFERENCIADO
 = MSG27 ;MSG-REFERENCIAR EIXO Z
;
IG40_REF_Z ;MICRO DE REFERENCIA EIXO Z
= DECEL3 ;MICRO REFERENCIA Z
;
;LIBERACOES ***********************************************************
;
DRENA1 ;DRIVE ENABLE EIXO X - CNC
= DRENA3 ;DRIVE ENABLE EIXO Z - CNC
= SERVO3ON ;SERVO LIGADO EIXO Z - CNC
;
DRENA1 ;DRIVE ENABLE EIXO X - CNC
AND NOT LOPEN ;EIXO SOB CONTROLE DE DRIVE
= TG2 100 2000
;
T100
= OG40_FREIO_Z ;LIBERA FREIO EIXO Z
;
SPENA1 ;SPEED ENABLE EIXO X - CNC
= SPENA3 ;SPEED ENABLE EIXO Z - CNC
;
NOT SPENA3 ;NAO SPEED ENABLE EIXO Z - CNC
OR NOT OG40_FREIO_Z ;NAO FREIO EIXO Z
= INHIBIT3 ;BLOQUEIO EIXO Z
;
END
;
;**********************************************************************
L80; SISTEMA DE LUBRIFICACAO DOS EIXOS ********************************
;**********************************************************************
;
NOT COMANDO ;COMANDO DESLIGADO
AND IG80_PRES_LUB ;PRESSAO LUBRIF GUIAS
= ERR23 ;ERRO-PRESSOSTATO LUB_GUIAS ENROSCADO
;
COMANDO ;COMANDO LIGADO
AND NOT IG80_DISJ_LUB ;DISJUNTOR MOTOR LUBRIFICACAO GUIAS
= MSG40 ;MSG-FALHA MOTOR LUB_GUIAS
;
COMANDO ;COMANDO LIGADO
AND NOT IG80_NIV_LUB ;NIVEL OLEO LUBRIFI. GUIAS
= MSG41 ;MSG-BAIXO NIVEL OLEO LUB_GUIAS
;
OG80_MT_LUB ;LUBRIFICANDO GUIAS DOS EIXOS
= TG2 16 20000 ;TEMPO DE SUPERVISAO DO PRESSOSTATO
;
T16 ;TEMPO DE SUPERVISAO DO PRESSOSTATO
= SET MSG42 ;MSG-NAO ATINGIDO PRESSAO LUBRIFICACAO
;
OG80_MT_LUB ;LUBRIFICANDO GUIAS DOS EIXOS
= MSG43 ;MSG-LUBRIFICANDO GUIAS
;
()= CEN 11 ;HABILITA CONTADOR PARA LUBRIFICACAO
;
COMANDO ;COMANDO LIGADO
AND NOT ERR23 ;NAO ERRO-PRESSOSTATO ENROSCADO
AND NOT MSG40 ;NAO MSG-FALHA NO MOTOR
AND NOT MSG41 ;NAO MSG-BAIXO NIVEL LUBRIFICACAO
AND NOT MSG42 ;NAO MSG-NAO ATINGUE PRESSAO
 AND NOT OG80_MT_LUB ;NAO LUBRIFICANDO GUIAS
AND M2011 ;PULSO 1 SEG
= CUP 11 ;INCREMENTA CONTADOR
;
DFU COMANDO ;LIGAMENTO DO COMANDO
OR CPS C11 GT R9 ;CONTADOR IGUAL PARAMETRO DE USUARIO
OR DFU B18R562 ;PULSO TECLA DE LUBRIFICACAO
= CPR 11 0 ;ZERA CONTADOR DE LUBRIFICACAO
= SET OG80_MT_LUB ;LIGA BOMBA LUBRIFICACAO CABECOTE
;
OG80_MT_LUB ;LUBRIFICANDO GUIAS DOS EIXOS
AND IG80_PRES_LUB ;ATINGIDO PRESSAO DE LUBRIFICACAO
= TG2 17 R11 ;LUBRIFICACAO CONFORME TELA DE USUARIO
;
T16 ;TEMPO DE SUPERVISAO DO PRESSOSTATO
OR T17 ;LUBRIFICACAO CONFORME TELA DE USUARIO
OR RESETOUT ;TECLA RESET
OR NOT COMANDO ;COMANDO DESLIGADO
OR ERR23 ;ERRO-PRESSOSTATO ENROSCADO
OR MSG40 ;MSG-FALHA NO MOTOR
OR MSG41 ;MSG-BAIXO NIVEL LUBRIFICACAO
; OR MSG42 ;MSG-NAO ATINGUE PRESSAO
= RES OG80_MT_LUB ;DESLIGA LUBRIFICACAO DAS GUIAS
;
END
;
;**********************************************************************
L85; REFRIGERACAO FERRRAMENTA *****************************************
;**********************************************************************
;
COMANDO ;COMANDO LIGADO
AND ( OG85_MT_REFR ;REFRIGERACAO LIGADA
AND DFD I27 ) ;IG85_DISJ_MTREF ) ;DISJ. MOTOR REFRIGERACAO
OR ( NOT I27 ;IG85_DISJ_MTREF ;NAO DISJUNTOR MOTOR DE REFRIGERACAO
AND ( B12R562 ;TECLA LIGA REFRIGERACAO
OR M1908 )) ;FUNCAO M8 - LIGA REFRIGERACAO
= SET MSG65 ;MSG-FALHA MOTOR REFRIG_FERRAMENTA
;
COMANDO ;COMANDO LIGADO
AND NOT MSG65 ;NAO MSG-FALHA NO MOTOR
AND ( B12R562 ;TECLA LIGA REFRIGERACAO
OR M1908 ) ;FUNCAO M8 - LIGA REFRIGERACAO
= SET OG85_MT_REFR ;LIGA REFRIGERACAO
;
NOT COMANDO ;COMANDO DESLIGADO
OR MSG65 ;MSG-FALHA NO MOTOR
OR B28R562 ;TECLA DESLIGA REFRIGERACAO
OR NOT I27 ;IG85_DISJ_MTREF ;NAO DISJUNTOR REFRIGERACAO
OR M1902 ;FUNCAO M2 - FIM DE PROGRAMA
OR M1909 ;FUNCAO M9 - DESLIGA REFRIGERACAO
OR M1930 ;FUNCAO M30 - FIM DE PROG. RET. INI.
OR RESETOUT
= RES OG85_MT_REFR ;DESLIGA REFRIGERACAO
= RES M1908
= RES M1909
;
END
;
;**********************************************************************
L87; TRANSPORTADOR DE CAVACOS *****************************************
;**********************************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT IG87_DISJ_TC ;NAO DISJUNTOR MOTOR TRANS. CAVACO
= MSG70 ;MSG-FALHA MOTOR TRANSP_CAVACOS
;
;COMANDO ;COMANDO LIGADO
; AND NOT IG87_TC_ENROSC ;NAO FIM DE CURSO TRANSPORTADOR
; = MSG71 ;MSG-TRANSP_CAVACOS ENROSCADO
;
COMANDO ;COMANDO LIGADO
AND NOT MSG71 ;MSG-TRANSP_CAVACOS ENROSCADO
AND NOT MSG70 ;MSG-FALHA MOTOR TRANSP_CAVACOS
AND IG87_TC_ENROSC ;FIM DE CURSO TRANSPORTADOR
AND DFU B11R562 ;TECLA LIGA TRANSPORTADOR
AND T33 ;TEMPO PARA REVERSAO
OR ( NOT B27R562 ;NAO TECLA DESLIGA/REVERTE TRANSP.
AND NOT MSG71 ;NAO MSG-TRANSP_ENROSCADO
AND NOT MSG70 ;NAO MSG-FALHA MOTOR
AND OG87_MT_TC_AVA ) ;TRANSP_CAVACOS SENTIDO CONTRARIO
= OG87_MT_TC_AVA ;MOTOR - AVANCA TRANSP_CAVACOS
;
COMANDO ;COMANDO LIGADO
AND NOT MSG70 ;NAO MSG-FALHA MOTOR
AND NOT OG87_MT_TC_AVA ;NAO AVANCA TRANSPORTADOR
AND B27R562 ;TECLA DESLIGA/REVERTE TRANSP.
AND ( T33 ;TEMPO PARA REVERSAO
OR OG87_MT_TC_RET ) ;RETORNA TRANSPORTADOR
= OG87_MT_TC_RET ;MOTOR - RETORNA TRANSP_CAVACOS
;
NOT OG87_MT_TC_AVA ;NAO AVANCA TRANSPORTADOR
AND NOT OG87_MT_TC_RET ;NAO RETORNA TRANSPORTADOR
= TG2 33 1000 ;TEMPO PARA REVERSAO
;
END
;
;**********************************************************************
L91; FIXACAO DA FERRAMENTA ********************************************
;**********************************************************************
;
COMANDO ;COMANDO LIGADO
AND NOT IG91_DISJ_MTFF ;NAO DISJUNTOR MOTOR FIXA O FERR.
= MSG75 ;MSG-FALHA MOTOR FIX_FERRAMENTA
;
OG91_MT_SOLTAR ;SOLTAR FERRAMENTA
= SET MSG76 ;MSG-FERRAMENTA_SOLTA
;
OG91_MT_FIXAR ;FIXAR FERRAMENTA
= TG2 32 3000 ;TEMPO PARA CANCELAR MENSAGEM
;
T32 ;TEMPO PARA CANCELAR MENSAGEM
= RES MSG76 ;CANCELA MSG-FERRAMENTA SOLTA
;
COMANDO ;COMANDO LIGADO
AND ( MANUAL ;MODO MANUAL
OR M1900 ) ;MO - PARADA PROGRAMADA
AND NOT MSG75 ;FALHA NO MOTOR FIXACAO
AND NOT OG10_MP_CW ;MOTOR FRESA SENTIDO HOR
 AND NOT OG10_MP_CCW
AND ( IG91_PED_SOL_FER
OR B29R562 )
AND NOT IG91_PED_FIX_FER
AND NOT B13R562
AND ( T31
OR OG91_MT_SOLTAR )
= OG91_MT_SOLTAR
;
COMANDO
AND ( MANUAL
OR M1900 )
AND NOT MSG75
AND NOT OG10_MP_CW
AND NOT OG10_MP_CCW
AND NOT IG91_PED_SOL_FER
AND ( IG91_PED_FIX_FER
OR B13R562 )
AND ( T31
OR OG91_MT_FIXAR )
= OG91_MT_FIXAR
;
NOT OG91_MT_FIXAR
AND NOT OG91_MT_SOLTAR
= TG2 31 1000
;
END
;
;**********************************************************************
L100 ;SUBROTINA PARA DECODIFICACAO DE FUNCOES M's *********************
;**********************************************************************
;
CPS MBCD* EQ $00 = M1900
CPS MBCD* EQ $02 = M1902
CPS MBCD* EQ $03 = M1903
CPS MBCD* EQ $04 = M1904
CPS MBCD* EQ $05 = M1905
CPS MBCD* EQ $08 = M1908
CPS MBCD* EQ $09 = M1909
CPS MBCD* EQ $30 = M1930
CPS MBCD* EQ $99 = M1999
;
END
;MOTOR FRESA SENTIDO ANTI-HOR
;PEDAL SOLTAR
;TECLA SOLTAR
;PEDAL FIXAR
;TECLA FIXAR
;TEMPO PARA LIBERAR ACIONAMENTO DO MOTOR
;MOTOR - SOLTAR FERRAMENTA
;MOTOR - SOLTAR FERRAMENTA
;COMANDO LIGADO
;MODO MANUAL
;M0 - PARADA PROGRAMADA
;FALHA NO MOTOR FIXACAO
;MOTOR FRESA SENTIDO HOR
;MOTOR FRESA SENTIDO ANTI-HOR
;PEDAL SOLTAR
;PEDAL FIXAR
;TECLA FIXAR
;TEMPO PARA LIBERAR ACIONAMENTO DO MOTOR
;MOTOR - FIXAR FERRAMENTA
;MOTOR - FIXAR FERRAMENTA
;NAO FIXANDO FERRAMENTA
;NAO SOLTANDO FERRAMENTA
;TEMPO P/ LIB ACIONAMENTO DO MOTOR
;M00:PARADA PROGRAMADA
;M02:FIM DE PROGRAMA
;M03:GIRO HORARIO DA FERRAMENTA
;M04:GIRO ANTI-HORARIO DA FERRAMENTA
;M05:PARADA DA FERRAMENTA
;M08:LIGA REFRIGERACAO
;M09:DESLIGA REFRIGERACAO
;M30:FIM DE PRG RET. AO INICIO
;M99:CANCELA REFERENCIA DOS EIXOS