DSP C5000

Chapter 21
Frequency Modulation
GMSK Modulation

Copyright © 2003 Texas Instruments. All rights reserved.

 Learning Objectives

 Overview of Digital Modulation

 Understanding GMSK Modulation
 Learning how to Implement a GMSK M
odulator on a C54

SIEE, Slide 2 Copyrig

 Digital Modulations
 Baseband and bandpass signalling are used to
transmit data on physical channels such as
telephone cables or radiofrequency channels.
 The source of data (bits or symbol) may be a
computer file or a digitized waveform (speech,
video…)
 The transmitted signal carries information about
the data and its characteristic changes at the same
rate as the data.
 When the signal carrying the data information
 Extends from 0 Hz upwards, the term baseband
signalling is used.
 Has its power centered on a central frequency fc,
the term bandpass signalling or modulation is
used.
SIEE, Slide 3 Copyrig
 Digital Modulation
 Modulation is used because:
 The channel does not include the 0 Hz
frequency and baseband signalling is
impossible
 The bandwidth of the channel is split
between several channels for frequency
multiplexing
 For wireless radio-communications, the
size of the antenna decreases when the
transmitted frequency increases.

SIEE, Slide 4 Copyrig

 Carrier Frequency
 In simple modulation schemes, a single
frequency signal, the carrier, is modified
at the rate of the data.
 The carrier is commonly written as:
fc= Carrier frequency
A cos  2 f c t    A = Carrier Amplitude
 = Carrier phase

 The 3 main parameters of the carrier:

amplitude, phase and frequency can be
modified to carry the information
leading to: amplitude, phase and
frequency modulation.
SIEE, Slide 5 Copyrig
 Digital Modulation
 CPM: Continuous Phase Modulation
 Frequency or phase modulation
 Example: MSK, GMSK
 Characteristic: constant envelope modulation
 QAM: Quadrature Amplitude Modulation
 Example: QPSK, OQPSK, 16QAM
 Characteristic: High spectral efficiency
 Multicarrier Modulation
 Example: OFDM, DMT
 Characteristic: Muti-path delay spread tolerance,
effectivness against channel distortion

SIEE, Slide 6 Copyrig

 What is the Complex Envelope z(t) of a
Modulated Signal x(t) ?

x(t) z(t)e j2f ct  zI (t)cos 2fct   zQ(t)sin 2fct .

fc= Carrier frequency

z (t )   x(t )  jxH (t )  e  j 2 fct  z I (t )  jzQ (t )  A(t )e j (t )

z(t) = Complex envelope of x(t)
zI(t), zQ(t) are the baseband components
xH(t) = Hilbert transform of x(t) = x(t) with a phase shift of /2

S x (f) 1  S z (f  fc ) S z (f  fc ).
2
Sx(f) = Power spectral density of x(t)

SIEE, Slide 7 Copyrig

 Complex Envelope z of a Modulated Signal x
Frequency Domain

X(f) 1
1
f
0

2
2
1
Xa(f)
0
f

2
2
Z(f) 1

f
0

SIEE, Slide 8 Copyrig

 GMSK Modulation
 Gaussian Minimum Shift Keying.

 Used in GSM and DECT standards.

 Relevant to mobile communications
because of constant envelope
modulation:
 Quite insensitive to non-linearities of power
amplifier
 Robust to fading effects
 But moderate spectral efficiency.

SIEE, Slide 9 Copyrig

 What is GMSK Modulation?
 Continuous phase digital frequency
modulation
 Modulation index h=1/2
 Gaussian Frequency Shaping Filter
 GMSK = MSK + Gaussian filter
 Characterized by the value of BT
 T = bit duration
 B = 3dB Bandwidth of the shaping filter
 BT = 0.3 for GSM
 BT = 0.5 for DECT
SIEE, Slide 10 Copyrig
 GMSK Modulation, Expression for the
Modulated Signal x(t)

x(t )  cos  2 f c t   (t )  with:

t 
 (t )  2 h   a s(  kT )d
k
 k 

ak = Binary data = +/- 1

h = Modulation index = 0.5
Normalization
s(t) = Gaussian frequency shaping filter 
1
s(t)= Elementary frequency pulse s( )d  2

SIEE, Slide 11 Copyrig

 GMSK Elementary Phase Pulse

t
q (t )   s( )d .


Elementary phase pulse =  (t )

t
 (t )  2 hq(t )  2 h  s ( )d .


n n
For t   nT , (n  1)T  (t )  2 h  ak q(t  kT )   a  (t  kT )
k
k  k 

 n

x(t )  cos  2 f c t  (t )   cos  2 f c t   a k (t  kT )  .
 k  

SIEE, Slide 12 Copyrig

 Architecture of a GMSK Modulator
G M S K m o d u la to r u s in g a V C O


k
a k t  kT  k
aks t  kT 

C oder r (t) h (t) VCO x(t)

B its ak

s (t )  r (t ) * h (t ) h
R e c ta n g u la r filte r G a u s s ia n filte r

GMSK modulator without VCO

cos  2 f ct 

cos()
 a   t  kT 
k 2h
k
t
 (t )

Bits ak
Coder s(t )  sin  2 f ct 
+ x (t )
 -
s(t )  r (t ) * h(t ) sin()

SIEE, Slide 13 Copyrig

 Equation for the Gaussian Filter h(t)

2  2 2 B 2 2 
h(t )  B exp   t 
ln(2)  ln(2) 
 ln(2) 2 
H ( f )  exp   2
f 
 2B 

The duration MTb of the gaussian pulse

is truncated to a value inversely
proportional to B.
BT = 0.5, MTb = 2Tb
BT = 0.3, MTb = 3 or 4Tb

SIEE, Slide 14 Copyrig

 Frequency and Phase Elementary Pulses
 (t)
Tbg(t ) Elementary frequency pulse Elementary phase pulse
/2
1.6

BT b  
BTb  
1.4
0.5

BTb  0,5
1.2
BT  0 .5
b
0.4
BTb  0,3
1
BT  0 .3
b

0.3 0.8

0.6
0.2
0.4

0.1
0.2

0 0
-2 -1 0 1 2 -2 -1 0 1 2

t in number of bit periods Tb t in number of bit period Tb

The elementary frequency pulse is

the convolution of a square pulse
r(t) with a gaussian pulse h(t).
Its duration is (M+1)Tb.

SIEE, Slide 15 Copyrig

 GMSK Signals
1
Binary sequence 0 t
-1
0 5 10 15 20
1
GMSK modulated Signal 0 t
-1
0 5 10 15 20
5
 (t ) 0 t
in rd -5
0 5 10 15 20
1
z I ( t )  cos  ( t )  0 t
-1
0 5 10 15 20
1
z Q ( t )  sin  ( t )  0 t
-1
0 5 10 15 20

SIEE, Slide 16 Copyrig

 Power Spectral Density of GMSK Signals

Power spectral density of the complex envelope of GMSK, BT=0.3, fe=8, T=1.
Logarithmic scale
20

-20

-40

-60

-80

-100

-120

-140
0 0.5 1 1.5 2 2.5 3 3.5 4
Frequency normalized by 1/T

SIEE, Slide 17 Copyrig

 Implementing a GMSK Modulator on a DSP
 Quadrature modulation can be used:
 The DSP calculates the phase  and the 2
baseband components zI and zQ and sends
them to the DAC.
 Or a modulated loop can be used.
 In this case, the DSP generates the
instantaneous frequency finst signal that is
sent to the DAC.

f inst  h  ak s (  kT ).
k 

SIEE, Slide 18 Copyrig

 Calculation of the Instantaneous Frequency
 finst is obtained by a simple filtering of
the bit sequence ak by a FIR filter of
impulse response s(n).

Open Matlab routine

pul_phas.m to calculate s(n).
Explanation of parameters
are given in following slides.

SIEE, Slide 19 Copyrig

 Expression for the Baseband Components
 The baseband components zI and zQ are
modulated in amplitude by the 2
quadrature carriers.

x(t )  cos  2 f ct   (t )   cos   (t )  cos  2 f ct   sin  (t )  sin  2 f ct 

x(t )  z I (t )cos  2 f ct   zQ (t )sin  2 f ct 

SIEE, Slide 20 Copyrig

 Baseband Components and Carriers
 Baseband components
z I (t )  cos   (t ) 
zQ (t )  sin  (t ) 
 The carriers are generally RF analog
signals generated by analog oscillators
 However, we will show how they could
be generated digitally if the value of fc
were not too high.
CarrierI  cos  2 f ct 
CarrierQ  sin  2 f ct 
SIEE, Slide 21 Copyrig
 Calculation of the Baseband
Components on a DSP
 Calculate the phase  at time mTS
 Ts the sampling frequency.
 Read the value of cos() and sin()
from a table.

n
For t   nT , (n  1)T   (t )   a  (t  kT ).
k
k 
n
 (mTS )   a  (mT
k 
k S  kT ).

SIEE, Slide 22 Copyrig

 Calculation of the Elementary Pulse Phase
with Matlab
 The elementary pulse phase (mTS) is
calculated with Matlab and stored in
memory.
 The duration LT of the evolutive part of
(mTS) depends on the value of BT.
  is called phi in the matlab routine.
t
 (t )  2 h  s ( )d


 (t )  0 t  0
 (t )  h t  LT

SIEE, Slide 23 Copyrig

 Calculation of the Elementary Pulse Phase
with Matlab 1/2
Beginning of the matlab routine
function [phi,s]=pul_phas(T_over_Ts,L,BT,T)

Ts=T/ T_over_Ts ;
% calculates the number of samples in phi in the interval 0 - LT
Open Matlab
Nphi=ceil(T_over_Ts*L);
routine
% calculates the number of samples in T pul_phas.m
Nts=ceil(T_over_Ts);

phi=zeros(1,Nphi);
s=zeros(1,Nphi);

sigma=sqrt(log(2))/2/pi/(BT/T)

SIEE, Slide 24 Copyrig

 Calculation of the Elementary Pulse Phase
with Matlab 2/2
End of the matlab routine

t=[-L*T/2:Ts:L*T/2];
t=t(1:Nphi);
ta=t+T/2;
tb=t-T/2;

Qta=0.5*(ones(1,Nphi)+erf(ta/sigma/sqrt(2)));
Qtb=0.5*(ones(1,Nphi)+erf(tb/sigma/sqrt(2)));
expta=exp(-0.5*((ta/sigma).^2))/sqrt(2*pi)*sigma;
exptb=exp(-0.5*((tb/sigma).^2))/sqrt(2*pi)*sigma;

phi=pi/T/2*(ta.*Qta+expta-tb.*Qtb-exptb);

s=1/2/T*(Qta-Qtb);
SIEE, Slide 25 Copyrig
 Using the Matlab Routine
 Start Matlab
 Use:
 T_over_Ts=8
 L=4
 T=1
 BT=0.3
 call the routine using to calculate the
phase pulse phi ( ) and the pulse s:
 [phi,s]=pul_phas(T_over_Ts,L,BT,T)
 Plot the phase phi and the shaping pulse s
 plot(phi)
 plot(s)
SIEE, Slide 26 Copyrig
 Results of Matlab Routine

SIEE, Slide 27 Copyrig

 Results for phi
 For L=4 and T_over_Ts=8, we obtain 32
samples for phi. Matlab gives the
following values for phi:
 Phi= [0.0001, 0.0002, 0.0005, 0.0012, 0.0028,
0.0062, 0.0127, 0.0246, 0.0446, 0.0763, 0.1231,
0.1884, 0.2740, 0.3798, 0.5036, 0.6409, 0.7854,
0.9299, 1.0672, 1.1910, 1.2968, 1.3824, 1.4476,
1.4945, 1.5262, 1.5462, 1.5581, 1.5646, 1.5680,
1.5696, 1.5703, 1.5706]
 After this evolutive part of phi, phi stays
equal to /2 (1.57).
 To calculate , the evolutive part and
the constant part of the elementary
phase pulse phi are treated separately.
SIEE, Slide 28 Copyrig
 Calculation of 
 Separation of evolutive and constant
parts of phi.
For t   nT ,(n  1)T 
n nL n
 (t )   a  (t  kT )   a  (t  kT )  
k 
k
k 
k
k  n  L 1
ak (t  kT ) with:

 (t )  0 t  0
h
 (t )  h  t  LT
2
 nL n n
 (t )   ak   ak (t  kT )  phimem( n)   ak (t  kT )
2 k  k  n  L 1 k  n  L 1

SIEE, Slide 29 Copyrig

 Memory Part and Evolutive Part of 

For t   nT ,(n  1)T 


phimem( n)  phimem( n  1)  a( n  L) .
2

n
 (t )  phimem(n)  
k  n  L 1
ak (t  kT )

t  mTS
n
 (mTS )  phimem(n)  
k  n  L 1
ak ( mTS  kT )

SIEE, Slide 30 Copyrig

 Recursive Calculation of 
 Names of variables
 Phase = 
 phi = array of evolutive part of ,
 Nphi samples = LT/Ts
 Ns = number of samples per bit = T/Ts
 an = binary sequence (+/- 1)
 2 calculation steps:
 Calculate 
 Calculate zI=cos() and zQ=sin() by table
reading

SIEE, Slide 31 Copyrig

 Calculation of : Initialization
 Initialization step:
 L first bit periods, phimem = 0
 At bit L+1, phimem is set to a1 /2.
 Principle of the initialization processing:
 FOR i=1 to i=L
 for j=(i-1)Ns+1 to j=(i-1)Ns+Nphi
 phase((i-1)Ns+j)= phase((i-1)Ns+j)+phi(j)an(i)
 Endfor
 endFOR
 phimem=an(1) /2

SIEE, Slide 32 Copyrig

 Calculation of : After Initialization
 FOR i=L+1 to last_bit
 For j=(i-1)Ns+1 to j=(i-1)Ns+Nphi
 phase((i-1)Ns+j)= phase((i-1)Ns+j)+phi(j)an(i)
 endFor
 For j=(i-1)Ns+1 to j=i Ns
 phase((i-1)Ns+j)= phase((i-1)Ns+j)+phimem
 xi=cos(phase(i-1)Ns+j)
 xq=sin(phase((i-1)Ns+j)
 endFor
 phimem=phimem+pi/2 an(i+1-L)
 endFOR
SIEE, Slide 33 Copyrig
 Coding and Wrapping the Phase Table
 The phase value in [-,[ is represented
by the 16-bit number Iphase
 Minimum phase = -, Iphase = -215.
 Maximum phase = (1-215), Iphase = 215-1.

15
2 phase
Iphase 


SIEE, Slide 34 Copyrig

 Index for the table in Phase Calculation
 Phase increment between 2 table values:
 2 / Ncos and on Iphase 216/Ncos
 For Iphase, the index of the table is:
 i= Ncos Iphase 2-16
 Here Ncos 2-16 = 2-9,
 So the index in the table is given by shifting
Iphase 9 bits to the right.

SIEE, Slide 35 Copyrig

 Coding of phi
 The quantized values of phi can be
obtained with Matlab:
 phi= round(phi*2^15/pi);
 phi is defined and initialized in the file
phi03.asm as:

.ref phi
.sect "phi"
phi .word 1,2,5,13,29,65,133,256
.word 465,795,1284,1965,2858,3961,5252,6685
.word 8192,9699,11132,12423,13526,14419,15100,15589
.word 15919,16128,16251,16319,16355,16371,16379,16382

SIEE, Slide 36 Copyrig

 Calculation of sin() and cos() by
Table Lookup
 We use a table of cosine values
 Length of the table Ncos=128, circular
buffer
 Contents of the table: cosine of angles i
uniformly distributed between - and . 
i  N cos N cos 
i  i   ,  1
N  2 2 
 deb_cos = first address of the table
 mid_cos = address of the table middle
 cos(i ) is at address mid_cos + i

SIEE, Slide 37 Copyrig

 Calculation of sin() and cos() by
Table Lookup
 Conversion of the phase modulo 2:
 Wrapping phase in [-,[
 Done by a macro: testa02pi
* Macro to wrap the phase between - et , phase is in ACCU A
testa02pi .macro
SUB #8000h,A,B ; sub -2^(15)
BC suite1?, BGEQ ; test if phase is in [0,2pi[
SUB #8000h,A ; sub -2^(15)
SUB #8000h,A ; SUB -2^(15)
B suite?
suite1? ADD #8000h,A,B ; add -2^(15)
BC suite?,BLT
ADD #8000h,A ; add -2^(15)
ADD #8000h,A ; add -2^(15)
suite? ; end of test
.endm

SIEE, Slide 38 Copyrig

 Generating the Sine Values from a Table of
Cosine Values
 To generate sin() from the table of
cosine values, we use:
 cos(/2 - ) or cos(-/2 + ) or cos(3/2+ )
 If i is the index of the cosine, for the sine we
use:
 i-Ncos/4 if i>= -Ncos/4
 i+3Ncos /4 if i < Ncos/4.

SIEE, Slide 39 Copyrig

 Implementation on a C54x, Test Sequence
 We can test the GMSK modulation on a
given periodical binary sequence an:
 an=[ 0 1 1 0 0 1 0 1 0 0]
 These bits are stored in a circular buffer:
 Size NB = 10
 Declaration of a section bits aligned on an
address which is a multiple of 16 bits.

AR5 deb_bit

NB

an

SIEE, Slide 40 Copyrig

 Testing the Generation of  on the C54x,
Results Buffer
 We calculate  and store it in a buffer
pointed by AR1. The size of the result
buffer is 1000 words.

AR1 resu

1000

Buffer for the last 1000 result values of 

SIEE, Slide 41 Copyrig

 Testing the Generation of  on the C54x
Buffers

AR4 phi AR3 deb_phase

Nphi Nphi

phi phase

Circular Buffer for phi (evolutive part) Circular Buffer for the variable phase
Allocated at an address multiple of 64 Allocated at an address multiple of 64
(Nphi = 32) (Nphi = 32)

SIEE, Slide 42 Copyrig

 Listing for the Calculation of 
Definitions
.mmregs
.global debut,boucle
.global deb_cos, phi
.global deb_phase
.global resu
Nphi .set 32
Nphim .set -32
L .set 4
Ncos .set 128
Nsur2 .set 64
Nsur4 .set 32
NB .set 10
NS .set 8
.bss resu,1000
SIEE, Slide 43 Copyrig
 Listing for the Calculation of 
Macro for phase wrapping

* Definition of macro of phase wrapping testa02pi

testa02pi .macro
SUB #8000h,A,B ;sub -2^(15)
BC suite1?, BGEQ ;test if phase in [0,2pi[
SUB #8000h,A ;sub -2^(15)
SUB #8000h,A ;sub -2^(15)
B suite?
suite1? ADD #8000h,A,B ;add -2^(15)
BC suite?,BLT
ADD #8000h,A ;add -2^(15)
ADD #8000h,A ;add -2^(15)
suite? ;end test wrapping [0,2pi[
.endm

SIEE, Slide 44 Copyrig

 Listing for the Calculation of 
Initialization of Registers and Buffers 1/2
.text
* Initialization of BK, DP, ACCUs, and ARi
debut: LD #0, DP
LD #0, A
LD #0, B
STM #deb_bit,AR5
STM #deb_cos,AR2
STM #deb_phase ,AR3
STM #phi,AR4
STM #resu,AR1
STM +1,AR0
STM #Nphi, BK
STM #(NS-1),AR7
RSBX OVM
SSBX SXM
SIEE, Slide 45 Copyrig
 Listing for the Calculation of 
Initialization of Registers and Buffers 2/2

* Initialization of the phase buffer

RPT #(Nphi-1)
STL A,*AR3+%
*initialization of phimem
LD *AR5,T
MPY #04000h,A ; -2^(14) an(1)(pi/2 an(1))
STL A,*(phimem)

SIEE, Slide 46 Copyrig

 Listing for the Calculation of 
Calculation for the first L bits
* processing for the first L bits
STM #(L-1),AR6
Ldeb STM #Nphi-1,BRC
RPTB fin-1 ; from k=0 to k=Nphi
LD *AR3,A ; accu=phase(k)
MAC *AR4+0%,*AR5,A ; A=phase(k)+an(i) phi(k)
testa02pi
STL A,*AR3+% ; A->phase(k)
NOP
fin NOP
STM #(NS-1), AR7
Nsbouc LD *AR3,A ; output of NS values
STL A,*AR1+ ; and reset at 0 of NS words
ST #0,*AR3+%
BANZ nsbouc,*AR7-

STM #NB, BK
MAR *AR5+%
STM #Nphi,BK
BANZ Ldeb, *AR6-

SIEE, Slide 47 Copyrig

 Listing for the Calculation of 
Calculation of the Following Bits 1/2
* begin of the infinite loop
boucle STM #Nphi-1,BRC
RPTB fin2-1 ; for k=0 to Nphi
LD *AR3,A ; accu=phase(k)
MAC *AR4+0%,*AR5,A ; A=phase(k)+an(i) phi(k)
testa02pi
STL A,*AR3+% ; A->phase(k)
fin2
* adding phimem to the NS first points of the array
* then taking them out and reset to 0 in phase
STM #NS-1,AR7
nsbouc2 LD *(phimem),B
ADD *AR3,B,A ; B=phimem+phase(k)
testa02pi
STL A,*AR1+
ST #0,*AR3+% ; 0->phase(k)
BANZ nsbouc2,*AR7- ; ....

SIEE, Slide 48 Copyrig

 Listing for the Calculation of 
Calculation of the Following Bits 2/2

fin3
* actualization of phimem
LD *(phimem),A
STM #NB, BK
MAR *+AR5(#unmL)%
LD *AR5,T
MAC #04000h,A ; -2^(14) an(1)(pi/2 an(1))
testa02pi
STL A,*(phimem)
MAR *+AR5(#L)%
STM #Nphi,BK
B boucle
.end

SIEE, Slide 49 Copyrig

 Illustration of the Phase Result Wrapped
Between - and 
 Plot under CCS the buffer of phase results

SIEE, Slide 50 Copyrig

 Generation of the Baseband Components
zI=cos() and zQ=sin()
 We calculate zI and zQ and we do not
need to save the phase any more.
 We output ZI and Zq, in this example
on DXR0 and DXR1.
 We need the table of constants for the
values of cosine.
 This table is defined in the file tabcos.asm
 The cosine values are given in format Q14.

SIEE, Slide 51 Copyrig

 File tabcos.asm

.def deb_cos,mid_cos
.sect "tab_cos"
deb_cos .word -16384,-16364,-16305,-16207,-16069,-15893,-15679,-15426
.word -15137,-14811,-14449,-14053,-13623,-13160,-12665,-12140
.word -11585,-11003,-10394,-9760,-9102,-8423,-7723,-7005
.word -6270,-5520,-4756,-3981,-3196,-2404,-1606,-804
.word 0,804,1606,2404,3196,3981,4756,5520
.word 6270,7005,7723,8423,9102,9760,10394,11003
.word 11585,12140,12665,13160,13623,14053,14449,14811
.word 15137,15426,15679,15893,16069,16207,16305,16364
.word 16384,16364,16305,16207,16069,15893,15679,15426
.word 15137,14811,14449,14053,13623,13160,12665,12140
.word 11585,11003,10394,9760,9102,8423,7723,7005
.word 6270,5520,4756,3981,3196,2404,1606,804
.word 0,-804,-1606,-2404,-3196,-3981,-4756,-5520
.word -6270,-7005,-7723,-8423,-9102,-9760,-10394,-11003
.word -11585,-12140,-12665,-13160,-13623,-14053,-14449,-14811
.word -15137,-15426,-15679,-15893,-16069,-16207,-16305,-16364
mid_cos .set deb_cos+64

SIEE, Slide 52 Copyrig

 Listing for the Calculation of zI and zQ
 The listing for definitions and
initializations is the same as before.
 Processing of the L first bits,
 Processing of the other bits
 (infinite loop)

SIEE, Slide 53 Copyrig

 Processing of the First L Bits 1/2
* Processing of the L first bits
STM #(L-1),AR6
Ldeb STM #Nphi-1,BRC
RPTB fin-1 ; from k=0 to Nphi
LD *AR3,A ; accu=phase(k)
MAC *AR4+0%,*AR5,A ; A=phase(k)+an(i) phi(k)
testa02pi
STL A,*AR3+% ; A->phase(k)
fin NOP
STM #(NS-1), AR7
Nsbouc LD *AR3,A ; output of NS values
SFTA A,-9,A
ADD #mid_cos,A,B
STLM B,AR1
NOP
NOP
LD *AR1,B
STL B,DXR0

SIEE, Slide 54 Copyrig

 Processing of the First L Bits 2/2
* Calculation of the sine
ADD #Nsur4,A,B
BC sui,BGT
ADD #(Nsur2),B
B sui1
sui SUB #Nsur2,B
sui1 ADD #mid_cos,B

STLM B,AR1
NOP
NOP
LD *AR1,A
STL A,DXR1
ST #0,*AR3+%
BANZ nsbouc,*AR7-

STM #NB, BK
MAR *AR5+%
STM #Nphi,BK
SIEE, Slide 55 Copyrig
 Processing of the Following bits 1 of 2
* begin the infinite loop
boucle STM #Nphi-1,BRC
RPTB fin2-1 ; for k=0 to Nphi
LD *AR3,A ; accu=phase(k)
MAC *AR4+0%,*AR5,A ; A=phase(k)+an(i) phi(k)
testa02pi
STL A,*AR3+% ; A->phase(k)
fin2
*phimem is added to the NS first points of the array
* then they are output and words are reset to 0 in buffer phase
STM #NS-1,AR7
nsbouc2 LD *(phimem),B
ADD *AR3,B,A ; A=phimem+phase(k)
testa02pi
SFTA A,-9,A
ADD #mid_cos,A,B
STLM B,AR1
NOP
NOP
LD *AR1,B
STL B,DXR0

SIEE, Slide 56 Copyrig

 Processing of the Following Bits 2 of 2
* Calculation of the sine
NOP
ADD #Nsur4,A,B
NOP
NOP
BC suii,BGT
ADD #(Nsur2),B
B suii1
suii SUB #(Nsur2) ,B
suii1 ADD #mid_cos,B
STLM B,AR1
NOP
NOP
LD *AR1,A
STL A,DXR1
ST #0,*AR3+% ; 0->phase(k)
BANZ nsbouc2,*AR7-
fin3
* actualization of phimem
LD *(phimem),A
STM #NB, BK
MAR *+AR5(#unmL)%
LD *AR5,T
MAC #04000h,A ; -2^(14) an(1)(pi/2 an(1))
testa02pi
STL A,*(phimem)
MAR *+AR5(#L)%
STM #Nphi,BK
B boucle
.end
SIEE, Slide 57 Copyrig
 Results Observed in CCS

SIEE, Slide 58 Copyrig

 Generation of 2 Quadrature Carriers
 Generation of:
 cos(2fct) and sin (2fct)
 fc is the frequency of the carrier
 In this example we choose fc=1/T
 Sampling frequency = 1/Ts = fS
 In RF applications, the carriers are not
generated by the DSP. It is only possible
to use the DSP for low values of fc.
 The angle (t)= 2fct is calculated then
the value of cos() is read from a table.

SIEE, Slide 59 Copyrig

 Calculation of the Angle of the Carriers
 Recursive calculation of the angle :

 (nTS )  2 f c nTS    (n  1)TS   2 f cTS    (n  1)Ts   

 The precision of the generated

frequency depends on the precision of
.
 The phase increment  corresponds to
an increment I to the integer that
represents .
I=216f T rounded to the closest
c S
integer.
SIEE, Slide 60 Copyrig
 Calculation of the Angle of the Carriers
 If the number of samples per period of
the carrier is a power of 2, 2k:
 I=216fcTS=2(16-k) is exact
 Then the precision of the generated
frequency depends only on the
precision of the sampling frequency.
 Otherwise, there is an error dfc in fc:
 |dfc|<2-17fS.
 Error in the amplitudes of the carriers
due to finite precision of the table
reading. (possible interpolation).
SIEE, Slide 61 Copyrig
 Implementation on a C54x
 We use: fs/fc=8=Ns.
 The cosine table has 128 Values in Q14.

AR1 deb_cos

128
Cosine
values

Circular buffer,Table of cosine

SIEE, Slide 62 Copyrig

 Implementation on a C54x
 Here k=3 (8 samples per period) and the
increment
 I=216fcTS=2(16-k) =213

 Simple case of fS/fc as an integer value, the

table is read with an offset from the pointer =
16 = 27/23 to generate a cosine with 8 samples
per period.
 We can work directly on the index i and not
on I.

SIEE, Slide 63 Copyrig

 Generation of the Cosine and Sine Carriers
 For the cosine:
 The circular buffer containing the cosine
values (length N) is accessed with AR1.
 Incremented by the content of AR0=16.
 AR1 initialized with deb_cos.
 For the sine:
 Same circular buffer accessed by AR2.
 AR2 initialized with deb_cos + Ncos/4.
 Decremented by AR0=16.
 Outputs (cos and sin) are sent to DXR0
and DXR1.
SIEE, Slide 64 Copyrig
 Generation of quadrature 2 Carriers
 File porteuse.asm
 A file associated with DXR0 and DXR1
is used to save visual results obtained
with the CCS simulator.
 Here cosine table goes from:
 0 to 2

SIEE, Slide 65 Copyrig

 Listing for the Generation of 2 Carriers 1 of 2
.mmregs
.global debut,boucle
Ncos .set 128
Nsur2 .set 64
Nsur4 .set 32
Inc .set 16
* Definition and initialization of Table of cosine
.sect "tab_cos"
deb_cos .word 16384,16364,16305,16207,16069,15893,15679,15426
.word 15137,14811,14449,14053,13623,13160,12665,12140
.word 11585,11003,10394,9760,9102,8423,7723,7005
.word 6270,5520,4756,3981,3196,2404,1606,804
.word 0,-804,-1606,-2404,-3196,-3981,-4756,-5520
.word -6270,-7005,-7723,-8423,-9102,-9760,-10394,-11003
.word -11585,-12140,-12665,-13160,-13623,-14053,-14449,-14811
.word -15137,-15426,-15679,-15893,-16069,-16207,-16305,-16364
.word -16384,-16364,-16305,-16207,-16069,-15893,-15679,-15426
.word -15137,-14811,-14449,-14053,-13623,-13160,-12665,-12140
.word -11585,-11003,-10394,-9760,-9102,-8423,-7723,-7005
.word -6270,-5520,-4756,-3981,-3196,-2404,-1606,-804
.word 0,804,1606,2404,3196,3981,4756,5520
.word 6270,7005,7723,8423,9102,9760,10394,11003
.word 11585,12140,12665,13160,13623,14053,14449,14811
.word 15137,15426,15679,15893,16069,16207,16305,16364

SIEE, Slide 66 Copyrig

 Listing for the Generation of 2 Carriers 2 of 2
.text
* Initializations of DP, and of the phase Ialpha at 0
* The phase Ialpha is in ACCU A, and the index of table in B
* attention we work in the part of ACCUs
* Initialize AR1 at mid_cos and AR0 at Nsur4
debut:
LD #0, DP
LD #0, A
STM #Ncos,BK
STM #deb_cos,AR1
STM #(deb_cos+Nsur4),AR2
STM #Inc, AR0

* endless loop
boucle:
LD *AR1+0%,A
STL A, DXR0
LD *AR2-0%,B
STL B,DXR0
* Return to the beginning of the endless loop
B boucle

SIEE, Slide 67 Copyrig

 Results Obtained with CCS

SIEE, Slide 68 Copyrig

 Tutorial
 The listing files for the precedent examples
can be found in the directory “tutorial”:
 Tutorial > Dsk5416 > Chapter 21 > Labs_modulation

SIEE, Slide 69 Copyrig

 Further Activities
 Application 5 for the TMS320C5416
DSK and for the TMS320C5510.
 Alien Voices. A very simple application showing the
effect of modulation on audio frequencies. It shows
how the carrier causes sum and difference
frequencies to be generated. Here it is used to
generate the strange voices used for aliens in science
fiction films and television.

SIEE, Slide 70 Copyrig